# Static websites
{ lib, config, ... }:
let
  inherit (import ./lib.nix config) terakoda havenisms blazestar;
  mkStaticSite = domain: let
    cleanDomain = lib.strings.stringAsChars (c: if c == "." then "-" else c) domain;
  in {
    "${cleanDomain}-static" = {
      image = "nginx:alpine";
      autoStart = true;
      volumes = [
        "/tank/web/${domain}/public:/usr/share/nginx/html:ro"
      ];
      labels = {
        "traefik.enable" = "true";
        "traefik.http.routers.${cleanDomain}.rule" = "Host(`${domain}`) || Host(`www.${domain}`)";
        "traefik.http.routers.${cleanDomain}.middlewares" = "${cleanDomain}-add-www@docker";
        "traefik.http.services.${cleanDomain}.loadbalancer.server.port" = "80";
        "traefik.http.middlewares.${cleanDomain}-add-www.redirectregex.regex" = "^https://${domain}/(.*)";
        "traefik.http.middlewares.${cleanDomain}-add-www.redirectregex.replacement" = "https://www.${domain}/\${1}";
        "traefik.http.middlewares.${cleanDomain}-add-www.redirectregex.permanent" = "true";
      };
    };
  };
in {
  virtualisation.oci-containers.containers = 
    mkStaticSite terakoda //
    mkStaticSite havenisms //
    mkStaticSite blazestar;
}